proc iml;

   /*------------------------------------------------------*/
   /*               The CHOOSE Module                      */
   /*                                                      */
   /* We consider all the possible choices of M objects    */
   /* from a set of M+N. There is a sequential way of      */
   /* ordering them. The module CHOOSE gives you the next  */
   /* choice when you supply a given selection and the     */
   /* parameters M and N. The vector VEC is input and      */
   /* consists of integers from 1 to M+N. Examples if you  */
   /* are choosing five objects from a set of 8:           */
   /* 1) Input mvec0=[1 2 3 5 7] and get mvec1=[1 2 3 5 8] */
   /* 2) Input mvec0=[1 3 4 7 8] and get mvec1=[1 3 5 6 7] */
   /* This module is used inside the module PERMTEST.      */
   /*------------------------------------------------------*/

start choose(vec,mvec0,m,n, mvec1);
mvec1=mvec0;
do place=m to 1 by -1;
   if mvec0[1,place]<n+place then do;
      mvec1[1,place]=mvec1[1,place]+1;
      if place<m then mvec1[1,place+1:m]=
                 vec[1,place+1:m]+mvec1[1,place]-place;
      return;
   end;
end;
finish;

   /*-----------------------------------------------------*/
   /*                 The PERMTEST Module                 */
   /*                                                     */
   /* This module performs the permutation test.          */
   /*                                                     */
   /* Input:                                              */
   /*    1) TEST, a character string that specifies the   */
   /*       scores used. The possible choices are the     */
   /*       same as the ones in PROC NPAR1WAY Ñ WILCOXON, */
   /*       MEDIAN, VW, and SAVAGE.                       */
   /*    2) M, the sample size of the CLASS variable      */
   /*       level designated "first".                     */
   /*    3) N, the sample size of the CLASS variable      */
   /*       level designated "second".                    */
   /*    4) SUMSCORE, the sum of the scores for the       */
   /*       "first" class level for the desired test      */
   /*                                                     */
   /* Returns PVAL, a 1x3 vector that gives the exact     */
   /* significance level for lower-tailed, upper-tailed,  */
   /* and two-tailed hypotheses.                          */
   /*-----------------------------------------------------*/

start permtest(test,m,n,sumscore, pval);
test=upcase(test);
mn=m+n;
size=round(gamma(mn+1)/(gamma(m+1)#gamma(n+1)),1);
vec=1:mn;
pval=j(1,3,0);
mvec0=vec[1,1:m];
if test='SAVAGE' then savvec=1/(mn-vec+1);
do i = 1 to size;
   if test='.' | test='WILCOXON' then score0=mvec0;
   if test='MEDIAN' then score0=(mvec0>(mn+1)/2);
   if test='VW' then score0=probit(mvec0/(mn+1));
   if test='SAVAGE' then do;
      score0=j(1,m,.);
      do j = 1 to m;
         mj=mvec0[1,j];
         score0[1,j]=sum(savvec[1,1:mj])-1;
      end;
   end;
   rankstat=sum(score0);
   if rankstat<=sumscore then pval[1,1]=pval[1,1]+1;
   if rankstat>=sumscore then pval[1,2]=pval[1,2]+1;
   pval[1,3]=2*min(pval[1,1],pval[1,2]);
   if i<size then do;
      run choose(vec,mvec0,m,n, mvec1);
      mvec0=mvec1;
   end;
end;
pval=pval/size;
if pval[1,3]>1 then pval[1,3]=1;
reset noname;
chead={"Lower-Tail" "Upper-Tail" "Two-Tail"};
print pval[colname=chead];
finish;