/**********************************************************************/


data _power_;

      /*  On the following line, enter an estimate of the overall    */
      /*  success probability (p=), the test's significance level    */
      /*  (level=), the alternative hypothesis specified as the      */
      /*  difference between p1 and p2 (diff=), and the minimum      */
      /*  (nmin=) and maximum (nmax=) sample sizes to be considered. */                                 */
   p=.3;   level=.05;   diff=.12;   nmin=10;   nmax=1000;

   /* Compute power */

      /* Create macro variables for output labeling.                 */
   call symput('p',trim(left(p)));
   call symput('level',trim(left(level)));
   call symput('diff',trim(left(diff)));

      /* Select 'nice' range of total sample sizes.                  */
   diforder=10**(max(floor(log10(nmax-nmin+1e-8)),1)-1);
   normlen=(nmax-nmin)/diforder;
   step=diforder*((normlen<=20)+2*(20<normlen<=40)+5*(40<normlen<=100));
   do n=nmin, nmin+step-mod(nmin+step,step) to nmax by step, nmax;

         /* Power and beta computation */
      power=1-probnorm(-probit(level/2)-diff*sqrt(n/(4*p*(1-p)))) +
            probnorm( probit(level/2)-diff*sqrt(n/(4*p*(1-p))));
      beta=1-power;
      output;
      if n=round(nmax) then stop;
   end;
run;

proc print noobs split='/';
   var n power beta;
   label n="Total/Sample/Size";
   title  "Power for comparing two independent proportions";
   title2 "Total sample size to be split equally between the groups";
   title3 "Overall p=&p; p1-p2=&diff; test level=&level";
run;


/**********************************************************************/