/* METHOD TWO:  Use the ANNOTATE facility to draw      */ 
   /* a plot line on PROC GCHART output.                  */ 
                                                             
data anno;                                                   
   set fy1992;                                               
   length function color style $8;                           
   retain xsys ysys '2' hsys '3' color 'black'               
          line 1 when 'a';                                   
   midpoint=month; y=earnings;                               
                                                             
      /* place plot symbol                                */ 
   function='label';                                         
   position='+';     /* center the text                   */ 
   style='swissb';                                           
   size=5;           /* size of the character is 5%       */ 
   text='$';                                                
   output;                                                  
                                                            
      /* locate beginning of plot line                    */
   if _n_=1 then do;                                        
      function='move';                                      
      output;                                               
   end;                                                     
                                                            
      /* draw plot line                                   */
   else do;                                                 
      function='draw';                                      
      size=.25;        /* width of line is .25%           */
      output;                                               
   end;                                                     
   run;                                                     
                                                            
goptions reset=global;                                      
   title1 height=6 pct 'JLR Enterprises';                   
   title2 height=4 pct 'Semi-Annual Report';                
                                                            
   /* A FOOTNOTE statement is used to simulate a legend   */
   /* that will identify the chart contents.              */
footnote box=1 blank=yes height=4 pct color=graycc          
         font=swissb '03'x                                  
         color=black font=swissl height=3 pct               
         ' SALES      -$- EARNINGS';                        
                                                            
axis1 offset=(5);                                           
axis2 label=none order=0 to 500 by 100 offset=(0,0); 
pattern1 color=graycc value=solid;                   
                                                     
proc gchart data=fy1992;                             
   format month monname3.;                           
   vbar month / frame                                
                discrete                             
                sumvar=sales                         
                maxis=axis1                          
                raxis=axis2                          
                space=5                              
                annotate=anno;                       
run;                                                 
quit;