/* Set global options for text font, color and height. */
goptions ftext=swissl ctext=black                           
         htext=2 pct rotate=landscape;                      
                                                            
   /* Generate data to be used for the graphs.            */
data fy1992;                                                
   input month date7. sales earnings;                       
   label month='1992';                                      
   cards;                                                   
01jan92 375  90                                             
01feb92 420 120                                             
01mar92 400 210                                             
01apr92 360 170                                             
01may92 280 150                                             
01jun92 320 140                                             
;                                                           
                                                            
   /* METHOD ONE:  Use the NEEDLE interpolation method    */
   /* with the WIDTH= option on a SYMBOL definition.      */
title1 height=6 pct 'JLR Enterprises';                      
title2 height=4 pct 'Semi-Annual Report';                   

   /* A FOOTNOTE statement is used to simulate a legend   */
   /* that identifies the chart contents.                 */
footnote box=1 blank=yes height=4 pct                       
         color=graycc font=swissb '03'x                     
         color=black font=swissl height=3 pct               
         ' SALES      -$- EARNINGS';                        
                                                            
axis1 order='01jan92'd to '01jun92'd                        
      by month offset=(5) major=none;                       
axis2 label=none order=0 to 500 by 100 offset=(0,0);        
symbol1 color=graycc interpol=needle                        
        value=none width=200;                               
symbol2 color=black interpol=join                           
        font=swissb value=$ height=5 pct                    
        width=3;                                            

proc gplot data=fy1992;                                     
   format month monname3.;                                  
   plot sales*month=1 earnings*month=2 /  overlay           
                                          frame             
                                          haxis=axis1       
                                          vaxis=axis2;      
run;                                                        
quit;